Warum noch ein Access-Buch?
Für wen ist das Buch?
Jetzt bestellen
+ direkter Download des eBooks!
Nur EUR 59,95!
Fehler gefunden?
Bitte melden!
Wünsche an das Buch?
Her damit!
Was denken die Leser über dieses Buch?
Lesen Sie aktuelle Rezensionen!
Kapitel des noch nicht veröffentlichten Buchs zum Downloaden, Probelesen und Kommentieren
Beispieldatenbanken
Zusätzliches Material

Das Buch im HTML-Format

Für unbestimmte Zeit bieten Addison-Wesley und André Minhorst den kompletten Inhalt des Buchs als Download an. Schauen Sie rein und informieren Sie sich über den Inhalt! Und wenn Ihnen das Buch nützlich erscheint und Sie glauben, dass Sie etwas gelernt haben oder durch das Gelesene sogar etwas Zeit und somit Geld bei Ihrer Arbeit einsparen konnten, können Sie sich ja beim Autor und beim Verlag revanchieren - beispielsweise durch den Kauf dieses Buchs.

Am schönsten wäre es natürlich, wenn Sie das Buch direkt hier bestellen - Sie erhalten das Buch dann direkt vom Verlag, und der Autor und Verlag haben dann noch mehr davon, als wenn Sie es anderswo kaufen.

Danke für Ihr Interesse!

16.3.16 Datensatz neu anlegen oder aktualisieren?

16.3.17 Neuen Datensatz anlegen

Die Funktion CreatePerson gibt die Daten des anzulegenden Objekts an die Methode Create des Datenzugriffsobjekts weiter. Dies geschieht in der Form, dass zunächst ein Personen-Objekt mit den Eigenschaften der Person erstellt und dieses dann an das Datenzugriffsobjekt übergeben wird.

Public Function CreatePerson(strVorname As String, _
    strNachname As String, strStrasse As String, strPLZ As String, _
    strOrt As String) As Long

    Dim objPerson As clsPerson
    Set objPerson = New clsPerson

    With objPerson
        .Vorname = strVorname
        .Nachname = strNachname
        .Strasse = strStrasse
        .PLZ = strPLZ
        .Ort = strOrt
    End With

    If objPersonDAO.Create(objPerson) = True Then
        CreatePerson = objPerson.PersonID
    Else
        MsgBox "Die Person konnte nicht angelegt werden.", _
            vbOKOnly + vbExclamation, "Fehler beim Anlegen von Daten"
    End If

    Set objPerson = Nothing

End Function

Listing 16.46: Die Funktion CreatePerson des Controller-Objekts erwartet die zu speichernden Eigenschaften des Person-Objekts als Parameter

Die Create-Methode kümmert sich nun um das Anlegen des Datensatzes in der Tabelle tblPersonen. Dabei wird neben dem Anlegen des Datensatzes auch die Eigenschaft PersonID mit dem in der Tabelle angelegten Wert gefüllt. Wenn das Anlegen erfolgreich war, liefert die Methode den Wert True zurück. Die Methode aus Listing 16.46 kann dann aus dem per Referenz übergebenen Objekt den neuen Wert der Eigenschaft PersonID auslesen.

Public Function Create(objPerson As clsPerson) As Long

    On Error GoTo Create_Err

    Dim db As DAO.Database
    Dim rst As DAO.Recordset

    Set db = CurrentDb
    Set rst = db.OpenRecordset _
        ("SELECT * FROM tblPersonen", dbOpenDynaset)

    With objPerson
        rst.AddNew
        rst![Vorname] = .Vorname
        rst![Nachname] = .Nachname
        rst![Strasse] = .Strasse
        rst![PLZ] = .PLZ
        rst![Ort] = .Ort
        .PersonID = rst![PersonID]
        rst.Update
    End With

    Create = True

Create_Exit:
    On Error Resume Next
    Set rst = Nothing
    Set db = Nothing
    Exit Function

Create_Err:
    Create = False
    GoTo Create_Exit

End Function

Listing 16.47: Die Create-Methode des Datenzugriffsobjekts legt einen neuen Datensatz auf Basis des übergebenen Objekts an

Nächster Abschnitt:

16.3.18 Aktualisieren eines Datensatzes

© 2006-2008 André Minhorst Alle Rechte vorbehalten.