Warum noch ein Access-Buch?
Für wen ist das Buch?
Jetzt bestellen
+ direkter Download des eBooks!
Nur EUR 59,95!
Fehler gefunden?
Bitte melden!
Wünsche an das Buch?
Her damit!
Was denken die Leser über dieses Buch?
Lesen Sie aktuelle Rezensionen!
Kapitel des noch nicht veröffentlichten Buchs zum Downloaden, Probelesen und Kommentieren
Beispieldatenbanken
Zusätzliches Material

Das Buch im HTML-Format

Für unbestimmte Zeit bieten Addison-Wesley und André Minhorst den kompletten Inhalt des Buchs als Download an. Schauen Sie rein und informieren Sie sich über den Inhalt! Und wenn Ihnen das Buch nützlich erscheint und Sie glauben, dass Sie etwas gelernt haben oder durch das Gelesene sogar etwas Zeit und somit Geld bei Ihrer Arbeit einsparen konnten, können Sie sich ja beim Autor und beim Verlag revanchieren - beispielsweise durch den Kauf dieses Buchs.

Am schönsten wäre es natürlich, wenn Sie das Buch direkt hier bestellen - Sie erhalten das Buch dann direkt vom Verlag, und der Autor und Verlag haben dann noch mehr davon, als wenn Sie es anderswo kaufen.

Danke für Ihr Interesse!

16.3.17 Neuen Datensatz anlegen

16.3.18 Aktualisieren eines Datensatzes

Das Aktualisieren bestehender Datensätze erfolgt analog. Diesmal ruft die Methode SavePerson die Funktion UpdatePerson auf, wobei im Vergleich zum Anlegen des Datensatzes der Wert der Eigenschaft PersonID mit übergeben wird.

Private Function UpdatePerson(lngPersonID As Long, strVorname As String, _
    strNachname As String, strStrasse As String, strPLZ As String, _
    strOrt As String)

    Dim objPerson As clsPerson

    Set objPerson = New clsPerson

    With objPerson
        .PersonID = lngPersonID
        .Vorname = strVorname
        .Nachname = strNachname
        .Strasse = strStrasse
        .PLZ = strPLZ
        .Ort = strOrt
    End With

    If Not objPersonDAO.Update(objPerson) = True Then
        MsgBox "Die Person konnte nicht aktualisiert werden.", _
            vbOKOnly + vbExclamation, "Fehler beim Aktualisieren"
    End If

End Function

Listing 16.48: Vorbereitung der Aktualisierung eines Datensatzes im Controller-Objekt

Die Methode Update des Datenzugriffsobjekts öffnet eine Datensatzgruppe, die lediglich einen Datensatz enthält - den mit der übergebenen PersonID.

Public Function Update(objPerson As clsPerson) As boolean

    On Error GoTo Update_Err

    Dim db As DAO.Database
    Dim rst As DAO.Recordset

    Set db = CurrentDb
    Set rst = db.OpenRecordset _
        ("SELECT * FROM tblPersonen WHERE [PersonID] = " _
        & objPerson.PersonID, dbOpenDynaset)

    With objPerson
        rst.Edit
        rst![Vorname] = .Vorname
        rst![Nachname] = .Nachname
        rst![Strasse] = .Strasse
        rst![PLZ] = .PLZ
        rst![Ort] = .Ort
        rst.Update
    End With
    Update = True

Update_Exit:
    On Error Resume Next
    Set rst = Nothing
    Set db = Nothing
    Exit Function

Update_Err:
    Update = False
    GoTo Update_Exit

End Function

Listing 16.49: Aktualisieren eines Datensatzes auf Basis des passenden Objekts

Nächster Abschnitt:

16.3.19 Löschen eines Datensatzes

© 2006-2008 André Minhorst Alle Rechte vorbehalten.